'TomGaines @2006
'1) Install DVDProfiler two or more times into different folders
'2) Start first DVDProfiler installation.
'3) Enter the registration information of the first user account
'4) Close DVDProfiler
'5) Start this script by double-clicking it
'6) Enter path to the first DVDProfiler
'7) Choose a name for the resulting shortcut script
'8) Repeat steps 2-7 for all other DVDProfiler installation
'RESULT: For each DVDProfiler installation/registration combination a start up script has been generated.
'Call these instead of dvdpro.exe to start the specific DVDProfiler


Option Explicit

Dim WSHShell, RegisterKey

Set WSHShell = CreateObject("WScript.Shell")

dim ProgramFiles, Process
set Process = WSHShell.Environment("PROCESS")
ProgramFiles = Process("ProgramFiles")

dim ProfilerPath, ScriptName
ProfilerPath = InputBox("Enter the path to the Profiler installation which should be used with the last saved user information:", "Profiler Path", ProgramFiles + "\InterVocative Software\DVD Profiler\dvdpro.exe")
if ProfilerPath = "" then wscript.quit
ScriptName = InputBox("Choose a filename for the generated script (without extension)", "Script Name", "StartProfiler")
if ScriptName = "" then wscript.quit

dim fso: set fso = CreateObject("Scripting.FileSystemObject")
dim script: set script = fso.CreateTextFile(ScriptName + ".vbs", true)

RegisterKey = "HKCU\Software\InterVocative Software\DVD Profiler\"

dim MyProfilerAlias, MyProfilerPassword, ContributionAuthorization
MyProfilerAlias = WSHShell.RegRead(RegisterKey & "MyProfilerAlias")
MyProfilerPassword = WSHShell.RegRead(RegisterKey & "MyProfilerPassword")
ContributionAuthorization = WSHShell.RegRead(RegisterKey & "ContributionAuthorization")
dim RegFName, RegKey, RegLName
RegFName = WSHShell.RegRead(RegisterKey & "RegFName")
RegLName = WSHShell.RegRead(RegisterKey & "RegLName")
RegKey = WSHShell.RegRead(RegisterKey & "RegKey")

script.WriteLine "Set WSHShell = WScript.CreateObject(" + chr(34) + "WScript.Shell" + chr(34) + ")"
script.WriteLine "WSHShell.RegWrite " + chr(34) + RegisterKey + "MyProfilerAlias" + chr(34) + ", " + chr(34) + MyProfilerAlias + chr(34) + ", " + chr(34) + "REG_SZ" + chr(34)
script.WriteLine "WSHShell.RegWrite " + chr(34) + RegisterKey + "MyProfilerPassword" + chr(34) + ", " +  chr(34) + MyProfilerPassword + chr(34) + ", " + chr(34) + "REG_SZ" + chr(34)
script.WriteLine "WSHShell.RegWrite " + chr(34) + RegisterKey + "ContributionAuthorization" + chr(34) + ", " +  chr(34) + ContributionAuthorization + chr(34) + ", " + chr(34) + "REG_SZ" + chr(34)
script.WriteLine "WSHShell.RegWrite " + chr(34) + RegisterKey + "RegFName" + chr(34) + ", " +  chr(34) + RegFName + chr(34) + ", " + chr(34) + "REG_SZ" + chr(34)
script.WriteLine "WSHShell.RegWrite " + chr(34) + RegisterKey + "RegLName" + chr(34) + ", " +  chr(34) + RegLName + chr(34) + ", " + chr(34) + "REG_SZ" + chr(34)
script.WriteLine "WSHShell.RegWrite " + chr(34) + RegisterKey + "RegKey" + chr(34) + ", " +  chr(34) + RegKey + chr(34) + ", " + chr(34) + "REG_SZ" + chr(34)

script.WriteLine "WSHShell.Run chr(34) + " + chr(34) + ProfilerPath + chr(34) + " + chr(34), 0"

script.close